As usual run Maple and load all the linear algebra progams.

Create a 3 by 3 matrix by evaluating: 
> A:=<<9, 6, -4>|<-9, -6, 6>|<-3, -3, 5 >>;

Use Maple to check the determinant of A and then form the matrix from which
we will get the eigenvalues:

> A1:=A-lambda*IdentityMatrix(3);

Use a pair of determinant row and column operations to create two zeros 
such that you could do a Laplace expansion with two zeros as coefficients. 

We can find the polynomial which contains the eigenvalues using:
> pA:=Determinant(A1); 
which is the so-called characteristic polynomial of A.
Note that the coefficient of pA without any lambda in is the determinant of A.

To manipulate polynomials you can use factor, expand, sort, etc. 
> factor(pA);

You can also plot pA to see the locations of the eigenvalues using

> plot(pA,lambda=1.5..4);

Find the eigenvector belonging to the eigenvalue 2 using 

> v1:=LinearSolve(subs(lambda=2,A1),<0,0,0>,free=s);

and verify that v1 when multiplied by A gives the expected result.

Find two eigenvectors of the eigenvalue lambda=3 similarly and check.
What are the solutions if you try to substitute a non eigenvalue?

Try to repeat the row and columns operation procedure for 
> C:= <<-6, 2, -3>|<-13, 15, -15>|<-2, 8, -7>>;
> C1:=C-lambda*IdentityMatrix(3);
but note that each way you try to do operations on C1 no easy cancellation occurs.

Use
> Eigenvalues(C);
to note what kind of factors you should get and try to create one. If after 5 minutes
if you have failed to create two zeros in a row, just evaluate 
> db:=factor(Determinant(C1)); 
to reassure yourself the answers Maple gave are indeed correct.

Find one of the three eigenvectors in C using RowOperation and/or Pivot and check for it or a multiple of it in the columns of P in

> (v,P):=Eigenvectors(C);

Extract another eigenvector from P and check it has the expected eigenvalue.

Make a diagonal matrix of eigenvalues using

> D1:=DiagonalMatrix(v);

Check that P and D1 multiplied is the same as C and P multiplied in that order.

Check these compound matrices have the expected values and vectors:
> Eigenvalues(k*C);
> Eigenvalues(MatrixInverse(C));
> Eigenvalues(Transpose(C));

Find the eigenvalues of this matrix using factor:

> E := Matrix([[3, -8, -3, 7], [2, -5, -3, 5], [2, -4, 2, -1], [2, -4, 0, 1]]);

Find two eigenvectors of the eigenvalue of multiplicity 2 by pivoting.

Create a matrix which has the eigenvalues from w:
> randomise():w:=RandomVector(3,generator=rand(1..9));
> Dw:=DiagonalMatrix(w);
> Q:=RandomMatrix(3,3,generator=rand(-3..3));
Choose Q as a random matrix for the eigenvectors and (if Q is 
non-singular) use diagonalisation to make J from Dw as follows:
> J:=Multiply(Multiply(Q,Dw),MatrixInverse(Q));

Check that the eigenvalues and eigenvectors of J are as you expect.

Maple can create the kth power of a matrix automatically:
> MatrixPower(Dw,k);
Check that when you use k=2 you get the same as
> Multiply(Dw,Dw);

Create a matrix B and its eigenvalues and eigenvectors:
> B:=Matrix([[6, -2, 1], [7, -3, 1], [-4, 2, 1]]);
using
> (v,P):=Eigenvectors(B);
(the v vector contains the eigenvalues, the P is the eigenvectors)

See what Maple produces for 
> MBk:=MatrixPower(B,k);
and check that the powers of the eigenvalues of B are in there.

Multiply P and a diagonal matrix of the powers of the eigenvalues, and 
the inverse of P to get Bk, the kth power of B.

> Bk:=Multiply(Multiply(P,MatrixPower(DiagonalMatrix(v),k)),MatrixInverse(P));

This should be something like MBk, but might be a bit different in some ways. You can see they are the same using 
> simplify(Bk-MBk);

Check that Bk and MBk are the same for small values of k:

> subs(k=2,Bk); subs(k=2,MBk); Multiply(B,B);

Check also for k=-1 and 0.